;
;  Copyright (C) 2008 Martin Furter <mf@rola.ch>
;
;  This file is part of avr_xc3jtag
;
;  avr_xc3jtag is free software; you can redistribute it and/or modify
;  it under the terms of the GNU General Public License as published by
;  the Free Software Foundation; either version 3, or (at your option)
;  any later version.
;
;  avr_xc3jtag is distributed in the hope that it will be useful,
;  but WITHOUT ANY WARRANTY; without even the implied warranty of
;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;  GNU General Public License for more details.
;
;  You should have received a copy of the GNU General Public License
;  along with avr_xc3jtag; see the file COPYING.  If not, write to
;  the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
;
;==============================================================================

.include "avr/atmega88.inc"

.global	usart2jtag_binary_data
	.type	usart2jtag_binary_data, @function


; uint16_t usart2jtag_binary_data()
usart2jtag_binary_data:
	; register usage:
	; r16  data register and scratch
	; r17  data carry register and scratch
	; r18  data carry register
	; r19  last line flag
	; r20  byte counter

	; push registers onto stack
	push r16
	push r17
	push r18
	push r19
	push r20

	; clear last line flag
	clr r19

NEXT_LINE:
	; wait for and read usart character
	lds r16, ADR_UCSR0A
	andi r16, 1<<RXC0
	breq NEXT_LINE
	lds r16, ADR_UDR0

	; '~' = 126
	cpi r16, '~'
	breq NORMAL_LINE
	; '!' = 33
	cpi r16, '!'
	breq LAST_LINE
	; invalid header
	ldi r24, 'A'
	rjmp RET_ERROR_INV_HDR

LAST_LINE:
	; set counter to 0, will be set to first byte of line
	clr r20
	; set last line flag
	inc r19
	; now read the line
	rjmp LINE_LOOP

NORMAL_LINE:
	; normal lines contain 54 raw data bytes
	ldi r20, 54

LINE_LOOP:
	; first 6 bit: byte 0 bits 7:2
	rcall USART_GET_6BIT
	brmi RET_ERROR_INV_CHAR
	; store for later use in r17 7:2
	mov r17, r16
	lsr r17
	lsr r17

	; second 6 bit: byte 0 bits 1:0 and byte 1 bits 7:4
	rcall USART_GET_6BIT
	brmi RET_ERROR_INV_CHAR
	; fill first byte with upper two bits, put lower 4 into r18 7:4
	swap r16
	mov r18, r16
	andi r16, 0x03
	or r16, r17
	andi r18, 0xF0

	; count down, output if not last byte of a line or first byte of last line
	dec r20
	; negative for the first byte of the last line only
	brmi LAST_LINE_CNT
	; next byte
	brne OUTPUT_FIRST_BYTE
	; end of line expected
	rjmp LAST_BYTE

LAST_LINE_CNT:
	; the first byte of the last line is the count of raw bytes following
	mov r20, r16
	rjmp READ_THIRD_CHAR

OUTPUT_FIRST_BYTE:
	; normal byte to output to SPI
	sts ADR_SPDR, r16

READ_THIRD_CHAR:
	; third 6 bit: byte 1 bits 3:0 and byte 2 bits 7:6
	rcall USART_GET_6BIT
	brmi RET_ERROR_INV_CHAR
	; fill second byte with upper 4 bits, put lower 2 into r17 7:6
	lsl r16
	lsl r16
	swap r16
	mov r17, r16
	andi r16, 0x0F
	or r16, r18
	andi r17, 0xC0

	; count down, output if not last byte of a line
	dec r20
	breq LAST_BYTE
	sts ADR_SPDR, r16

	; fourth 6 bit: byte 2 bits 5:0
	rcall USART_GET_6BIT
	brmi RET_ERROR_INV_CHAR
	; fill third byte
	or r16, r17

	; count down, output if not last byte of a line
	dec r20
	breq LAST_BYTE
	sts ADR_SPDR, r16

	; continue loop
	rjmp LINE_LOOP

LAST_BYTE:
	; last byte of a line, output if not last line
	tst r19
	brne READ_EOL
	sts ADR_SPDR, r16

READ_EOL:
	; read EOL, ignore CR, continue on LF
	; wait for and read usart character
	lds r17, ADR_UCSR0A
	andi r17, 1<<RXC0
	breq READ_EOL
	lds r17, ADR_UDR0

	cpi r17, 0x0d
	breq READ_EOL
	cpi r17, 0x0a
	brne RET_ERROR_INV_EOL

	; if not last line read next line
	tst r19
	; offset too high for 'breq NEXT_LINE'
	brne RET_LAST_BYTE
	rjmp NEXT_LINE

RET_LAST_BYTE:
	; return the last byte
	mov r24, r16
	clr r25
	rjmp POP_REGISTERS

RET_ERROR_INV_HDR:
	ldi r24, 'A'
	rjmp RET_ERROR
	
RET_ERROR_INV_CHAR:
	ldi r24, 'B'
	rjmp RET_ERROR
	
RET_ERROR_INV_EOL:
	ldi r24, 'C'
	rjmp RET_ERROR
	
RET_ERROR:
	ldi r25, 1

	; pop registers
POP_REGISTERS:
	pop r20
	pop r19
	pop r18
	pop r17
	pop r16

	; done
	ret


; wait for a character from usart
; convert to 6bit
; return in r16
; on error set N flag
USART_GET_6BIT:
	; wait for and read usart character
	lds r16, ADR_UCSR0A
	andi r16, 1<<RXC0
	breq USART_GET_6BIT
	lds r16, ADR_UDR0

	; '@' = 64
	cpi r16, 64
	brmi G6B_DIGIT
	breq G6B_AT_SIGN
	; '_' = 95
	cpi r16, 95
	brmi G6B_UPPER
	breq G6B_UNDERSCORE
	; 'a' = 97
	cpi r16, 97
	brpl G6B_LOWER

G6B_ERROR:
	sen
	ret

G6B_UPPER:
	; 'Z'+1 = 91
	cpi r16, 91
	brpl G6B_ERROR
	; 'A' = 65
	subi r16, 65
	cln
	ret

G6B_LOWER:
	; 'z'+1 = 123
	cpi r16, 123
	brpl G6B_ERROR
	; subtract 71: 'a' -> 26
	subi r16, 71
	cln
	ret

G6B_DIGIT:
	; '0' = 48
	cpi r16, 48
	brmi G6B_ERROR
	; '9'+1 = 58
	cpi r16, 58
	brpl G6B_ERROR
	; add 4: '0' -> 52
	subi r16, -4
	cln
	ret

G6B_UNDERSCORE:
	ldi r16, 62
	cln
	ret

G6B_AT_SIGN:
	ldi r16, 63
	cln
	ret

	.size	usart2jtag_binary_data, .-usart2jtag_binary_data