//=============================================================================
// SchlonzClientWindow.
//=============================================================================
class SchlonzClientWindow expands UWindowDialogClientWindow;

var UWindowComboControl ComboControls[11];
var UWindowEditControl ClusterLoadCountControl;
var string WeaponNames[11];
var UWindowSmallCloseButton CloseButton;

function Created()
{
	local int X, Y, Width;
	local int i, j;

	X = WinLeft + 0.025*WinWidth;
	Y = WinTop + 0.05*WinHeight;
	Width = 0.95 * WinWidth;

	for( i=0; i<ArrayCount(ComboControls); ++i )
	{
		ComboControls[i] = UWindowComboControl( CreateControl( class'UWindowComboControl', X, Y, Width, 1 ) );
		ComboControls[i].SetEditable(False);
		ComboControls[i].SetFont(F_Normal);
		ComboControls[i].SetText(WeaponNames[i]);
		ComboControls[i].SetHelpText("Replace all "$WeaponNames[i]$"s with...");
		for( j=0; j<ArrayCount(class'SchlonzMutator'.default.WeaponNames); j++ )
		{
			ComboControls[i].AddItem(class'SchlonzMutator'.default.WeaponNames[j]);
		}
		ComboControls[i].SetSelectedIndex(0);
		ComboControls[i].SetSize(Width, 1);
		ComboControls[i].SetButtons(True);
		ComboControls[i].WinLeft = X;
		ComboControls[i].EditBoxWidth = 0.4*Width;
		ComboControls[i].List.MaxVisible = Min(20-i,ArrayCount(ComboControls));
		ComboControls[i].List.bAlwaysOnTop = True;
		Y += 16;
	}
	// +++++ add bool ReplaceUnrealWeapons
	Y += 16;
	ClusterLoadCountControl = UWindowEditControl( CreateControl( class'UWindowEditControl', X, Y, Width, 1 ) );
	ClusterLoadCountControl.SetNumericOnly(True);
	ClusterLoadCountControl.SetFont(F_Normal);
	ClusterLoadCountControl.SetText("Cluster Redeemer Load Count");
	ClusterLoadCountControl.SetHelpText("Cluster Redeemer Load Count");
	ClusterLoadCountControl.SetSize(Width, 1);
	ClusterLoadCountControl.WinLeft = X;
	ClusterLoadCountControl.EditBoxWidth = 0.4*Width;
	Y += 16;
	CloseButton = UWindowSmallCloseButton(CreateControl(class'UWindowSmallCloseButton', X+Width-48, Y, 48, 16));
	CloseButton.SetHelpText("Close the Schlonz menu and save current settings.");
	SetComboValues();
}

/*
function SetReset()
{
}
*/

function AfterCreate()
{
	Super.AfterCreate();
	DesiredWidth = 330;
	DesiredHeight = ArrayCount(ComboControls)*16 + 40;
}

/*
function Notify(UWindowDialogControl C, byte E)
{
	local int S;
	
	Super.Notify(C, E);
	switch(E)
	{
	}
}
*/
function SetComboValues()
{
	ComboControls[0].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceEnforcer );
	ComboControls[1].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceBioRifle );
	ComboControls[2].SetSelectedIndex( class'SchlonzMutator'.default.ReplacePulseGun );
	ComboControls[3].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceShockRifle );
	ComboControls[4].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceMinigun );
	ComboControls[5].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceRipper );
	ComboControls[6].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceFlakCannon );
	ComboControls[7].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceEightBall );
	ComboControls[8].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceSniperRifle );
	ComboControls[9].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceRedeemer );
	ComboControls[10].SetSelectedIndex( class'SchlonzMutator'.default.ReplaceUnknownWeapon );
	ClusterLoadCountControl.SetValue( ""$class'SchlonzMutator'.default.RedeemerLoadCount );
}

function int xToInt( coerce int i )
{
	return i;
}

function Close(optional bool bByParent)
{
	class'SchlonzMutator'.default.ReplaceEnforcer = ComboControls[0].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceBioRifle = ComboControls[1].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplacePulseGun = ComboControls[2].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceShockRifle = ComboControls[3].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceMinigun = ComboControls[4].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceRipper = ComboControls[5].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceFlakCannon = ComboControls[6].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceEightBall = ComboControls[7].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceSniperRifle = ComboControls[8].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceRedeemer = ComboControls[9].GetSelectedIndex();
	class'SchlonzMutator'.default.ReplaceUnknownWeapon = ComboControls[10].GetSelectedIndex();
	class'SchlonzMutator'.default.RedeemerLoadCount = xToInt( ClusterLoadCountControl.GetValue() );

	class'SchlonzMutator'.SaveConfig();
	class'SchlonzMutator'.static.StaticSaveConfig();
	Super.Close(bByParent);
}

defaultproperties
{
	 WeaponNames(0)="Enforcer"
	 WeaponNames(1)="BioRifle"
	 WeaponNames(2)="PulseGun"
	 WeaponNames(3)="ShockRifle"
	 WeaponNames(4)="Minigun"
	 WeaponNames(5)="Ripper"
	 WeaponNames(6)="FlakCannon"
	 WeaponNames(7)="Rocketlauncher"
	 WeaponNames(8)="Sniper"
	 WeaponNames(9)="Redeemer"
	 WeaponNames(10)="Unknown"
}